Creating bodies

The most basic functions of this package create an object of type Body. There are a variety of such functions, a few of which we will demonstrate here. Generally speaking, we are interesting in creating the object and placing it in a certain position and orientation. We do this in two steps: we create the basic shape, centered at the origin with a default orientation, and then we transform the shape to a desired location and orientation. We will discuss the shapes in this notebook, and the transforms in the following notebook.

It is useful to stress that each body stores two types of points internally: the endpoints of the segments that comprise the body surface, and the midpoints of these segments. The midpoints are intended for use in downstream calculations, e.g. as forcing points in the calculations on immersed layers. The midpoints are simply the geometric averages of the endpoints, so endpoints are the ones that are transformed first, and midpoints are updated next.

using RigidBodyTools
using Plots

Creating a shape

Let's first create a shape. For any shape, we have to make a choice of the geometric dimensions (e.g, radius of the circle, side lengths of a rectangle), as well as the points that we use to discretely represent the surface. For this latter choice, there are two constructor types: we can specify the number of points (as an integer), or we can specify the nominal spacing between points (as a floating-point number).

The second approach is usually preferable when we use these tools for constructing immersed bodies. It is important to stress that the algorithms for placing points attempt to make the spacing as uniform as possible.

Let's create the most basic shape, a circle of radius 1. We will discretize it with 100 points first:

b = Circle(1.0,100)

Circular body with 100 points and radius 1.0
   Current position: (0.0,0.0)
   Current angle (rad): 0.0

Now we will create the same body with a spacing of 0.02

b = Circle(1.0,0.02)

Circular body with 312 points and radius 1.0
   Current position: (0.0,0.0)
   Current angle (rad): 0.0

This choice led to 312 points along the circumference. Quick math will tell you that the point spacing is probably not exactly 0.02. In fact, you can find out the actual spacing with dlengthmid. This function calculates the spacing associated with each point. (It does so by first calculating the spacing between midpoints between each point and its two adjacent points.)

dlengthmid(b)

312-element Vector{Float64}:
 0.020139095077842645
 0.02013909465345664
 0.020139095926384347
 0.020139093805429224
 0.020139096773551215
 0.02013909295946801
 0.020139097617965406
 0.020139092116941246
 0.020139098458258977
 0.020139091279220516
 ⋮
 0.020139098876402556
 0.02013909169742879
 0.020139098038677593
 0.020139092537724373
 0.02013909719615391
 0.020139093382138724
 0.020139096350192693
 0.020139094229301876
 0.020139095502170006

It is just a bit larger than 0.02.

A few other useful functions on the shape. To simply know the number of points,

length(b)

To find the outward normal vectors (based on the perpendicular to the line joining the adjacent midpoints):

nx, ny = normalmid(b)

([0.9999999999994525, 0.9997972500513201, 0.9991889560711664, 0.9981756172871938, 0.9967572242069879, 0.9949349397149403, 0.9927087488883317, 0.9900804735231573, 0.9870500969577222, 0.9836200924747993  …  0.9797908571175543, 0.9836197214184416, 0.9870504283171553, 0.9900801823981242, 0.9927089993067586, 0.9949347304092867, 0.9967573920603647, 0.9981754911583587, 0.9991890402708846, 0.9997972079172882], [1.0463939213204075e-6, 0.02013600729582963, 0.04026698480657073, 0.06037745484309014, 0.08046760833515793, 0.10052097161502202, 0.12053771144568437, 0.14050144464794798, 0.16041230032560236, 0.1802540254193159  …  -0.20002468924822323, -0.18025605020832927, -0.16041026138910267, -0.14050349612197227, -0.1205356490643909, -0.10052304325576243, -0.0804655290979954, -0.060379540001306534, -0.04026489541211434, -0.020138099234901622])

We can also plot the shape

plot(b)

Sometimes we don't want to fill in the shape (and maybe change the line color). In that case, we can use

plot(b,fill=:false,linecolor=:black)

Other shapes

Let's see some other shapes in action, like a square and an ellipse

b1, b2 = Square(1.0,0.02), Ellipse(0.6,0.1,0.02)
plot(plot(b1), plot(b2))

A NACA 4412 airfoil, with chord length 1, and 0.02 spacing between points.

b = NACA4(0.04,0.4,0.12,0.02)
plot(b)

A flat plate with no thickness

b = Plate(1.0,0.02)
plot(b)

and a flat plate with a 5 percent thickness (and rounded ends)

b = ThickPlate(1.0,0.05,0.01)
plot(b)

There are also some generic tools for creating shapes. A BasicBody simply consists of points that describe the vertices. The interface for this is very simple.

x = [1.0, 1.2, 0.7, 0.6, 0.2, -0.1, 0.1, 0.4]
y = [0.1, 0.5, 0.8, 1.2, 0.8, 0.6, 0.2, 0.3]
b = BasicBody(x,y)

Basic pointwise-specified body with 8 points
   Current position: (0.0,0.0)
   Current angle (rad): 0.0

plot(b)
scatter!(b,markersize=3,markercolor=:black)

However, this function does not insert any points along the sides between vertices. We have to do the work of specifying these points in the original call. For this reason, there are a few functions that are more directly useful. For example, we can create a polygon from these vertices, with a specified spacing between points distributed along the polygon sides

b = Polygon(x,y,0.02)

Closed polygon with 8 vertices and 188 points
   Current position: (0.0,0.0)
   Current angle (rad): 0.0

plot(b)
scatter!(b,markersize=3,markercolor=:black)

Alternatively, we can interpret those original points as control points for splines, with a spacing between points along the splines provided:

b = SplinedBody(x,y,0.02)

Basic pointwise-specified body with 198 points
   Current position: (0.0,0.0)
   Current angle (rad): 0.0

plot(b)
scatter!(b,markersize=3,markercolor=:black)

Body functions

RigidBodyTools.BasicBody — Type

BasicBody(x,y[,closuretype=ClosedBody]) <: Body

Construct a body by simply passing in the x and y coordinate vectors. The last point will be automatically connected to the first point. The coordinate vectors are assumed to be expressed in the body-fixed coordinate system. The optional closuretype specifies whether the body is closed (ClosedBody) or open (OpenBody). If closed, then the first and last points are assumed joined in operations that require neighbor points.

Creating bodies

Creating a shape

Other shapes

Body functions

Shape utilities